@echo off
setlocal

set VC9_COMMAND="%VS90COMNTOOLS%..\IDE\devenv.com"
set VC10_COMMAND="%VS100COMNTOOLS%..\IDE\devenv.com"
set VC11_COMMAND="%VS110COMNTOOLS%..\IDE\devenv.com"
set PROJDIR=..\..\eal\implementations\eal_gear3\projects\
set ARGS=/Rebuild

goto :MAIN

:: ************************************************************
:: * COMPILE PLATFORM VC9
:: ************************************************************

:COMPILE_PLATFORM_VC9

CALL :COMPILE_PROJECT %1 vc9 vcproj %VC9_COMMAND%

GOTO :EOF

:: ************************************************************
:: * COMPILE PLATFORM VC10
:: ************************************************************

:COMPILE_PLATFORM_VC10

CALL :COMPILE_PROJECT %1 vc10 vcxproj %VC10_COMMAND%

GOTO :EOF

:: ************************************************************
:: * COMPILE PLATFORM VC11
:: ************************************************************

:COMPILE_PLATFORM_VC11

CALL :COMPILE_PROJECT %1 vc11 vcxproj %VC11_COMMAND%

GOTO :EOF

:: ************************************************************
:: * COMPILE PROJECT
:: ************************************************************

:COMPILE_PROJECT

echo Compiling project for %1 with %2.

set PROJECT="%PROJDIR%eal_gear3_%1_%2.%3"
call %4 %PROJECT% %ARGS% "debug"
call %4 %PROJECT% %ARGS% "release"
call %4 %PROJECT% %ARGS% "retail"

GOTO :EOF

:: ************************************************************
:: * MAIN
:: ************************************************************

:MAIN

CALL :COMPILE_PLATFORM_VC10 win32
CALL :COMPILE_PLATFORM_VC10 win64
CALL :COMPILE_PLATFORM_VC10 xenon
CALL :COMPILE_PLATFORM_VC10 ps3_ppu
CALL :COMPILE_PLATFORM_VC10 vita
CALL :COMPILE_PLATFORM_VC10 orbis
CALL :COMPILE_PLATFORM_VC10 cafe
CALL :COMPILE_PLATFORM_VC11 durango
CALL :COMPILE_PLATFORM_VC11 win32
CALL :COMPILE_PLATFORM_VC11 win64
CALL :COMPILE_PLATFORM_VC11 ps3_ppu
CALL :COMPILE_PLATFORM_VC11 vita
CALL :COMPILE_PLATFORM_VC11 orbis
CALL :COMPILE_PLATFORM_VC11 cafe

endlocal