@echo off
SETLOCAL

SET SATELLITES=gear_core gear_testing
SET ROOT=..\..
SET CPP_INCLUDE=%VS100COMNTOOLS%..\..\VC\include

GOTO :MAIN


rem ****************************************************************************
:PLATFORM
rem ****************************************************************************

SET SATELLITE=%1
SET BLOBFILE=%2
CALL SET PLATFORM=%%BLOBFILE:%SATELLITE%_=%%
SET PLATFORM=%PLATFORM:.CPP=%

echo Updating header for platform %PLATFORM%
echo Satellite: %SATELLITE%
echo Blob: %BLOBFILE%
echo Platform: %PLATFORM%

rem **** ONLY CHECKOUT FILE on IOS & MAC
rem p4 edit %ROOT%\%SATELLITE%\config\configstruct_%PLATFORM%.h
rem p4 edit %ROOT%\%SATELLITE%\config\debug_%PLATFORM%.h
rem p4 edit %ROOT%\%SATELLITE%\config\release_%PLATFORM%.h
rem p4 edit %ROOT%\%SATELLITE%\config\retail_%PLATFORM%.h

HG.exe "%ROOT%\%SATELLITE%\%BLOBFILE%" --platform %PLATFORM% --msvcmode -I "%ROOT%" -I "%ROOT%\eal\sources" -I "%CPP_INCLUDE%" --moduleroot "%ROOT%\%SATELLITE%"

echo ****

GOTO :EOF


rem ****************************************************************************
:SATELLITE
rem ****************************************************************************

rem Make Sure the "config" directory exist if not create it
set CONFIGDIR=%ROOT%\%1\config
if NOT EXIST %CONFIGDIR% (
    md %CONFIGDIR%
)

echo Running headergen for satellite %1

if [%2] == [] (
    for /F "usebackq" %%B in (`dir /B "%ROOT%\%1\%1_*"`) DO CALL :PLATFORM %1 %%B
) else (
    CALL :PLATFORM %1 %1_%2.cpp
)


GOTO :EOF


rem ****************************************************************************
:MAIN
rem ****************************************************************************

for /F %%S IN ("%SATELLITES%") DO CALL :SATELLITE %%S %1

ENDLOCAL